This image shows some features of the discrete dynamical system

${\displaystyle z_{n+1}=f_{c}(z_{n})\,}$

based on complex quadratic polynomial :

${\displaystyle f_{c}(z)=z^{2}+c.\,}$.

When coeeficient ${\displaystyle c\,}$ goes inside Mandelbrot set from c=0.25 to c=-2 along horizontal axis ( imaginary part of c is zero) then stability index of periodic points is changing. This diagram shows what happens there.

Stability index:

• is zero for centers of hyperboic components of Mandelbrot set, like c= 0 or c = -1
• is 1 for root points, like c=0.25, c=-0.75 or c=-1.25

 load(cpoly); /* for bfallroots */
 /* ################  Definitions ############################ */

 /* use : load(cpoly);  roots:GiveRoots_bf(eq); */
 GiveRoots_bf(g):=
 block(
  [cc:bfallroots(expand(g)=0)],
  cc:map(rhs,cc),/* remove string "c=" */
  return(cc)
  )$ 

 /* functions for computing stability index of fixed points ;  returns real value */ 
 stability_beta(_c):=
 block(
  beta:(1+sqrt(abs(1-4*_c)))/2, 
  stability:abs(float(2*beta)), /* abs(multiplier(z)) */
  return(stability)
 );  

 stability_alfa(_c):=
 block(
  alfa:(1-sqrt(abs(1-4*_c)))/2, 
  stability:abs(float(2*alfa)), /* abs(multiplier(z)) */
  return(stability)
 ); 

 stability_2(c):=
 block(
 [eq,roots,z2],
  eq:z*z +z +c +1,  
  roots:GiveRoots_bf(eq), 
  z2:roots[1],
  m:4*z2*(z2*z2+c), /* multiplier */ 
  stability:cabs(float(m)), /*  abs(multiplier(z2)) */
  return(stability)
 ); 

 stability_3(c):=
 block(
  [eq,roots,z3],
  eq:z^6+z^5+(3*c+1)*z^4+(2*c+1)*z^3+(3*c^2+3*c+1)*z^2+(c^2+2*c+1)*z+c^3+2*c^2+c+1,  
  roots:GiveRoots_bf(eq), 
  z3:roots[1],
  m:8*z3*(z3^2+c)*((z3^2+c)^2+c), /* multiplier */ 
  stability:cabs(float(m)), /*  abs(multiplier(z3)) */
  return(stability)
 ); 

 stability_4(c):=
 block(
  [eq,roots,z4],
  eq:z^12+6*c*z^10+z^9+(15*c^2+3*c)*z^8+4*c*z^7+(20*c^3+12*c^2+1)*z^6+(6*c^2+2*c)*z^5+
  (15*c^4+18*c^3+3*c^2+4*c)*z^4+(4*c^3+4*c^2+1)*z^3+
  (6*c^5+12*c^4+6*c^3+5*c^2+c)*z^2+(c^4+2*c^3+c^2+2*c)*z+c^6+3*c^5+3*c^4+3*c^3+2*c^2+1,  
  roots:GiveRoots_bf(eq), 
  z4:roots[1],
  m:16*z4*(z4^2+c)*((z4^2+c)^2+c)*(((z4^2+c)^2+c)^2+c), /* multiplier */ 
  stability:cabs(float(m)), /*  abs(multiplier(z3)) */
  return(stability)
 ); 

 /* root points */
 root_pts:[-1.401154502237,-1.401151982029,-1.401140214699,-1.4010852713,-1.4008287424,-1.3996312389,
 -1.3940461566,-1.3680989394,-1.25,-0.75];

 ry:[1,1,1,1,1,1,1,1,1,1];

 /* centers of hyperbolic components of F1/2 family ( on real axis) */
 centers:[-1.381547484432061460,-1.31070264133683,-1,0]; /* periods: 8,4,2,1 */

 cy:[0,0,0,0];
 xMax:0.25;
 xMin:-1.39;
 yMin:0;
 yMax:xMax-xMin; /* for square image, but yMax can be > (xMax-xMin) */

 /* ------------------------------- main ------------------------------------------------- */
 load(draw);

 draw2d(
  terminal = png,
  file_name = "multiplier4_f",
  pic_height= 1100,
  pic_width=1100,
  user_preamble="set bmargin 7;set rmargin 25;set key out;set key top right",
  title       = "Stability index of periodic z-points for c along horizontal axis  for fc(z)= z*z +c ",
  ylabel     = "Stability index of z",
  xlabel     = "c",
  yrange = [yMin,yMax],
  /* period 1 */
  key    = "period 1 beta",
  color  = red,
  explicit(stability_beta,x,xMin,xMax),
  key    = "period 1 alfa",
  color  = blue,
  explicit(stability_alfa,x,xMin,xMax),
  /* period 2 */
  key    = "period 2 ",
  color  = green,
  explicit(stability_2,x,xMin,xMax),
  /* period 3 */
  key    = "period 3 ",
  color  = magenta,
  explicit(stability_3,x,xMin,xMax),
  /* period 4 */
  key    = "period 4 ",
  color  = purple,
  explicit(stability_4,x,xMin,xMax),
  /* grid and tics */
  xtics      = {-2,-1.94079980652948,-1.75487766624669,-1.3680989394,-1.31070264133683,-1.25,-1,-3/4,0,0.25}, 
  /* -2,root points,centers, 0 */
  xtics_axis = true,            /* plot tics on x-axis */
  xtics_rotate = true,
  ytics      = {0,1},
  grid       = true, /* draw grid*/
  /* special points */
  point_type    = filled_circle,
  point_size    = 0.5,
  points_joined = false,
  color         = black,
  key           = "root points",
  points(root_pts,ry),
  color         = red,
  key           = "centers",
  points(centers,cy)
 )$

Εγώ, ο κάτοχος των πνευματικών δικαιωμάτων αυτού του έργου, το δημοσιεύω δια του παρόντος υπό τις εξής άδειες χρήσης:

Το αρχείο διανέμεται υπό την άδεια Creative Commons Αναφορά προέλευσης-Παρόμοια διανομή 3.0 Μη εισαγόμενη

Είστε ελεύθερος:

• να μοιραστείτε – να αντιγράψετε, διανέμετε και να μεταδώσετε το έργο
• να διασκευάσετε – να τροποποιήσετε το έργο

Υπό τις ακόλουθες προϋποθέσεις:

• αναφορά προέλευσης – Θα πρέπει να κάνετε κατάλληλη αναφορά, να παρέχετε σύνδεσμο για την άδεια και να επισημάνετε εάν έγιναν αλλαγές. Μπορείτε να το κάνετε με οποιοδήποτε αιτιολογήσιμο λόγο, χωρίς όμως να εννοείται με οποιονδήποτε τρόπο ότι εγκρίνουν εσάς ή τη χρήση του έργου από εσάς.
• παρόμοια διανομή – Εάν αλλάξετε, τροποποιήσετε ή δημιουργήσετε πάνω στο έργο αυτό, μπορείτε να διανείμετε αυτό που θα προκύψει μόνο υπό τους όρους της ίδιας ή συμβατής άδειας με το πρωτότυπο.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

Παραχωρείται η άδεια προς αντιγραφή, διανομή και/ή τροποποίηση αυτού του εγγράφου υπό τους όρους της Άδειας Ελεύθερης Τεκμηρίωσης GNU, Έκδοση 1.2 ή οποιασδήποτε νεότερης έκδοσης δημοσιευμένης από το Ίδρυμα Ελεύθερου Λογισμικού· χωρίς Απαράλαχτους Τομείς, χωρίς Κείμενα Εξωφύλλου, και χωρίς Κείμενα Οπισθοφύλλου. Αντίγραφο της άδειας περιλαμβάνεται στην σελίδα με τίτλο GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

Μπορείτε να επιλέξετε την άδεια της προτίμησής σας.